ODROID C1+ 디스플레이 관련 문의입니다.

Post Reply
skwzang
Posts: 6
Joined: Thu Jun 27, 2019 3:19 pm
languages_spoken: english, korean
Has thanked: 2 times
Been thanked: 0
Contact:

ODROID C1+ 디스플레이 관련 문의입니다.

Unread post by skwzang » Wed Jul 10, 2019 12:05 pm

안녕하세요,
ODROID C1+ 디스플레이 관련 문의하기 위해 글 남깁니다.

현재 ODROID C1+를 사용하고 있고, ubuntu 18.04 버전을 사용하고 있습니다.

ODROID 부팅시 로그화면이 뜨게 되는데 대신에,

특정 이미지 파일을 LCD에 디스플레이 하거나 파이썬 등으로 작성한 프로그램을 동작시키고 싶은데

방법을 알 수 있을까요?

답변 부탁드립니다.

User avatar
tobetter
Posts: 3698
Joined: Mon Feb 25, 2013 10:55 am
languages_spoken: Korean, English
ODROIDs: X, X2, U2, U3, XU3, C1
Location: Paju, South Korea
Has thanked: 28 times
Been thanked: 117 times
Contact:

Re: ODROID C1+ 디스플레이 관련 문의입니다.

Unread post by tobetter » Wed Jul 10, 2019 12:10 pm

부팅로고는 흰바탕에 하드커널 로고가 나오는 상태인데, 이것을 다른 것으로 바꾸시고 싶은신건가요?

skwzang
Posts: 6
Joined: Thu Jun 27, 2019 3:19 pm
languages_spoken: english, korean
Has thanked: 2 times
Been thanked: 0
Contact:

Re: ODROID C1+ 디스플레이 관련 문의입니다.

Unread post by skwzang » Wed Jul 10, 2019 12:21 pm

tobetter wrote:
Wed Jul 10, 2019 12:10 pm
부팅로고는 흰바탕에 하드커널 로고가 나오는 상태인데, 이것을 다른 것으로 바꾸시고 싶은신건가요?
12.jpg
12.jpg (188.8 KiB) Viewed 138 times
부팅시 최초 다음과 같은 화면이 디스플레이 되고
34.jpg
34.jpg (609.33 KiB) Viewed 138 times
이후 부팅시 로그화면이 디스플레이 됩니다.

이를 디스플레이 하지 않고 특정 이미지를 출력하거나 특정 프로그램을 동작 시키고 싶습니다.

joy
Posts: 843
Joined: Fri Oct 02, 2015 1:44 pm
languages_spoken: english
ODROIDs: ODROID-C1+, XU4, X
Has thanked: 8 times
Been thanked: 35 times
Contact:

Re: ODROID C1+ 디스플레이 관련 문의입니다.

Unread post by joy » Wed Jul 10, 2019 4:27 pm

skwzang wrote:
Wed Jul 10, 2019 12:21 pm
이를 디스플레이 하지 않고 특정 이미지를 출력하거나 특정 프로그램을 동작 시키고 싶습니다.
[ Logo Display ]
현재 boot loader에서 잠깐 Logo Image를 출력할 수는 있습니다만,
이후 X login 화면까지 해당 화면을 안정적으로 유지하는 방법은 저희도 좀 들여다봐야 하는 내용입니다.
plymouth 등의 방법으로 계속 시도해보았으나 현재까지는 적당한 솔루션을 찾지는 못했습니다.

현상태에서 가능한 방법을 우선 공유해드립니다.

(1) booting log path 변경
우선 화면상에 출력되는 booting message는 아래와 같이 없애실 수 있습니다.
/media/boot/boot.ini의 아래 구문을 수정하시면 됩니다.

Code: Select all

# Default Console Device Setting
setenv condev "console=ttyS0,115200n8"        # on serial port
# setenv condev "console=tty0"                    # on display (HDMI)
# setenv condev "console=tty0 console=ttyS0,115200n8"   # on both
(2) bmp image 생성
아래 조건의 image 파일을 card의 vfat filesystem에 복사 (/media/boot/ 경로)
예 : 첨부파일 boot-logo.bmp.gz

Code: Select all

$ gzip -d boot-logo.bmp.gz
$ cp boot-logo.bmp  /media/boot/
(3) boot.ini에 아래 구문 추가

Code: Select all

# LOGO display
fatload mmc 0:1 ${loadaddr_logo} boot-logo.bmp
bmp display ${loadaddr_logo}
샘플 boot.ini를 첨부해드립니다.

Code: Select all

ODROIDC-UBOOT-CONFIG

# Possible screen resolutions
# Uncomment only a single Line! The line with setenv written.
# At least one mode must be selected.

# setenv m "480x272p60hz"       # 480x320
# setenv m "480x320p60hz"       # 480x320
# setenv m "480x800p60hz"       # 480x800
# setenv m "vga"                # 640x480
# setenv m "480p"               # 720x480
# setenv m "576p"               # 720x576
# setenv m "800x480p60hz"       # 800x480
# setenv m "800x600p60hz"       # 800x600
# setenv m "1024x600p60hz"      # 1024x600
# setenv m "1024x768p60hz"      # 1024x768
# setenv m "1360x768p60hz"      # 1360x768
# setenv m "1440x900p60hz"      # 1440x900
# setenv m "1600x900p60hz"      # 1600x900
# setenv m "1680x1050p60hz"     # 1680x1050
setenv m "720p"                 # 720p 1280x720
# setenv m "800p"               # 1280x800
# setenv m "sxga"               # 1280x1024
# setenv m "1080i50hz"          # 1080I@50Hz
# setenv m "1080p24hz"          # 1080P@24Hz
# setenv m "1080p50hz"          # 1080P@50Hz
# setenv m "1080p"                # 1080P@60Hz
# setenv m "1920x1200"          # 1920x1200

# HDMI DVI Mode Configuration
setenv vout_mode "hdmi"
# setenv vout_mode "dvi"
# setenv vout_mode "vga"

# HDMI BPP Mode
setenv m_bpp "32"
# setenv m_bpp "24"
# setenv m_bpp "16"

# Monitor output
# Controls if HDMI PHY should output anything to the monitor
setenv monitor_onoff "false" # true or false

# HDMI Hotplug Force (HPD)
# 1 = Enables HOTPlug Detection
# 0 = Disables HOTPlug Detection and force the connected status
setenv hpd "0"

# CEC Enable/Disable (Requires Hardware Modification)
# 1 = Enables HDMI CEC
# 0 = Disables HDMI CEC
setenv cec "0"

# PCM5102 I2S Audio DAC
# PCM5102 is an I2S Audio Dac Addon board for ODROID-C1+
# Uncomment the line below to __ENABLE__ support for this Addon board.
# setenv enabledac "enabledac"

# UHS Card Configuration
# Uncomment the line below to __DISABLE__ UHS-1 MicroSD support
# This might break boot for some brand models of cards.
setenv disableuhs "disableuhs"


# Disable VPU (Video decoding engine, Saves RAM!!!)
# 0 = disabled
# 1 = enabled
setenv vpu "1"

# Disable HDMI Output (Again, saves ram!)
# 0 = disabled
# 1 = enabled
setenv hdmioutput "1"

# Default Console Device Setting
setenv condev "console=ttyS0,115200n8"        # on serial port
# setenv condev "console=tty0"                    # on display (HDMI)
# setenv condev "console=tty0 console=ttyS0,115200n8"   # on both

# Enable/Disable ODROID-VU7 Touchscreen
setenv disable_vu7 "false" # false

# CPU Max Frequency
# Possible Values: 96 192 312 408 504 600 720 816
# 1008 1200 1320 1488 1536 1632 1728 and 1824
setenv max_freq "1536"
# setenv max_freq "1632"
# setenv max_freq "1728"
# setenv max_freq "1824"

###########################################

if test "${hpd}" = "0"; then setenv hdmi_hpd "disablehpd=true"; fi
if test "${cec}" = "1"; then setenv hdmi_cec "hdmitx=cecf"; fi
if test "${disable_vu7}" = "false"; then setenv hid_quirks "usbhid.quirks=0x0eef:0x0005:0x0004"; fi

# Boot Arguments
setenv bootargs "root=UUID=e139ce78-9841-40fe-8823-96a304a09859 rootwait ro ${condev} no_console_suspend 
fsck.repair=yes vdaccfg=0xa000 logo=osd1,loaded,0x7900000,720p,full dmfc=3 cvbsmode=576cvbs hdmimode=${m}
 m_bpp=${m_bpp} vout=${vout_mode} ${disableuhs} ${hdmi_hpd} ${hdmi_cec} ${enabledac} monitor_onoff=${moni
tor_onoff} max_freq=${max_freq} ${hid_quirks} fsck.repair=yes net.ifnames=0"

# LOGO display
fatload mmc 0:1 ${loadaddr_logo} boot-logo.bmp
bmp display ${loadaddr_logo}

# Booting
fatload mmc 0:1 0x21000000 uImage
fatload mmc 0:1 0x22000000 uInitrd
fatload mmc 0:1 0x21800000 meson8b_odroidc.dtb
fdt addr 21800000

if test "${vpu}" = "0"; then fdt rm /mesonstream; fdt rm /vdec; fdt rm /ppmgr; fi

if test "${hdmioutput}" = "0"; then fdt rm /mesonfb; fi

bootm 0x21000000 0x22000000 0x21800000"
혹시 사용하고자 하시는 모니터의 해상도가 어떻게 되나요?

[ 부팅시 프로그램 동작 ]
Ubuntu에서 부팅 시, 특정 프로그램을 동작시키기를 원하시면 아래의 방법을 사용하실수 있습니다.
1. /etc/rc.local 에 해당 프로그램 실행 command를 추가 후 reboot
또는
2. Ubuntu [Menu] -> [Preferences] -> [Startup Applications]에서 추가 후 reboot
Attachments
boot-logo.bmp.gz
(755.28 KiB) Downloaded 5 times

Post Reply

Return to “C0/C1/C1+/C2”

Who is online

Users browsing this forum: testki144 and 1 guest